label AAct3:
    #"I pull my car into the nearest parking spot and get out."

    #"This is my last bastion of hope. If Little Troodon doesn’t have a guitar, nowhere will."

    #"With an urgent pace I make my way through the tight streets lit in the soft orange light of hanging paper lanterns."

    #"I pass by stall after stall of trinkets and knick-knacks of varying quality, their vendors hassle me as I walk."

    #"My eyes dart around quickly trying to spot anything vaguely music related."
    A "Fuuuuck…"
    scene black with Dissolve(1)

    #"And as I continue to pass the stalls with no guitar in sight, a feeling of dread begins to creep over me."

    "I begin to think of possible backup gifts that I could get for Fang,{w} since Little Troodon didn't had any,{w} and any gift ideas that comes to mind is something insignificant or something that I’ve already gotten her."

    "As I’m stewing over my increasingly growing predicament, I suddenly find myself squinting in the bright lights of a neon sign."

    "I look up and wait for my eyes to adjust."

   
    play music 'audio/OST/Venetian Values.ogg' fadein 3 volume 0.5
    "“Dino Moe’s Pizza”"

    "I feel a slight sense of relief. That, or just plain desperation."

    "Moe knows this area pretty well. Maybe he can tell me where a music shop is."

    "I enter the restaurant, the familiar smell of oily pizza fills my senses."

    "Making my way towards the kitchen, I see Moe hard at work kneading pizza dough with his small arms."
    #i will need to change this line as well, this whole early dialouge and whatnot is dogpile
    "I clear my throat and make my presence known."

    scene moebackrooms with Dissolve(1)
    show Anon ChristNeut:
        xpos 0.50
        xzoom -1.0
    with Dissolve(0.5)
    show Moe ChristNeut:
        xpos 0.10
        xzoom -1.0
    with Dissolve(0.5)

    A "Hey Moe."

    show Moe ChristNeut:
        xzoom 1.0
    #make him turn slower?
    "He stops kneading and turns to face me. His eyes light up and a large toothy smile creases his face."

    Moe "AAAYYYY! Well if it isn’t my darlin’ Lucy’s absolute stud of a husband!"

    Moe "How tha heck are ya Anon?"

    "I manage a meek smile, but my voice betrays my desperation."

    A "Honestly, could be better right now Moe."

    Moe "Ah jeez, I’m sorry tah hear dat."

    Moe "Why don’t you sit down, have a slice wit ya Uncle Moe and tell im’ what’s goin’ on."

    A "I don’t have time for pizza, but I could definitely use some help right now."

    "Moe pulls out a chair and sits down and I follow suit. Concern is written all over his face."

    A "See, I’m trying to pick out the perfect gift for Fang, and so I thought of getting her a new guitar."

    A "The issue is that I’ve been to several different shopping centers at this point and I’ve found NOTHING!"

    A "I didn’t know where else to go so I thought of Little Troodon, and when I came around to your place I thought that you may know of a music shop around here."

    "Moe listens closely as I explain, and after I’m done, he closes his eyes and thinks hard for what feels like a long time."

    "When he’s done, he opens his eyes and finally speaks."

    Moe "I’m really sorry Anon, I racked my brain to see if I could rememba if der was any music shops around Little Troodon but I don’t think there are."

    "I let out a defeated sigh and rest my elbow on the table with my head in my hand."

    A "Alright… I appreciate you trying Moe."

    A "Time is running out so I need to get back out there and pick something else for Fang."

    "I get up from my chair and start to make my way back outside."

    show Anon ChristNeut:
        xzoom 1.0
        linear 0.70 xcenter 0.85
    with Dissolve(0.22)

    Moe "I know you’ll find something perfect for ‘er. Best of luck to ya!"

    show Anon ChristHapp:
        xzoom -1.0
    with Dissolve(0.25)

    "I turn my head and flash him another weak smile."
    #anon sprite go a bit to the right screen before turning around and smiling

    A "Thanks Moe."

    scene black with Dissolve(1)
    play music 'audio/OST/ballad_of_the_boot.ogg' fadein 3 volume 0.5

    "With an overwhelming feeling of defeat, I sit down on a bench outside of Moe’s and contemplate my options, mumbling out loud to myself."

    A "A new necklace? No, she never takes off the amber one I gave her."

    A "Merchandise from her favorite band? Too tacky, I want this to be special."

    A "A pet? Fuck no."

    "Another cold blast of wind causes me to shiver and huddle into my coat. I begin to feel snowflakes falling as they melt after contacting my bald head."

    "The night falls eerily quiet save for the distant sounds of merchants and customers."

    "Just when I think that all hope is lost, I hear a voice cut into my mind, interrupting my train of thought."

    scene snownight with Dissolve(1)
    play ambient 'audio/effects/outdoorLoop.ogg' fadein 2 volume 0.3
    show Anon ChristNeut:
        xpos 0.40
    with Dissolve(0.20)
    unknown "You know what they say, you snooze, you lose. And it looks like, you snost and you lost"
    #Xavier appears, slides in, note: finish this code under this note
    show fritatta with easeinleft:
        xcenter 0.30
        xzoom -1.0
    show Anon ChristNeut:
        xzoom -1.0
    "I immediately jump to my feet and whip around to face whoever the hell just said that."

    "I’m met with a confusing and slightly familiar sight."

    "It’s Reed’s weird uncle."

    unknown "It appears you have lost your way my shiny headed friend."

    A "...yeah, you’re not wrong man…"

    "Would he know?" 

    A "I’ve been searching for a new guitar for my wife, but every music shop I’ve been to is either closed or doesn’t have the right guitar!"

    unknown "As a matter of fact-er I do-er!"

    "I feel my whole face light up."
    #Anon smiles here?

    A "Really?! Where is it?!"

    unknown "Not so fast there buck-o. In order to receive the information you seek, we must complete…"

    unknown "{i}The Ritual!{/i}"
    #italics here

    "…you gotta be fucking kidding me."
    #maybe the postal dudes voiceline   

    unknown "In exchange for 20 of your earthly currency, I will give you the location as well as… this!"

    "He reaches into his fanny pack and produces something truly bizarre."

    "At first glance it looks like a speaker on account of the large black cylinder..."

    "...but what baffles me is what sits on top of it."

    "It looks like two rubber balls stacked on top of one another, and it has googly eyes and a nose glued onto it to make a face."

    A "Wha… what am I looking at exactly?"
    #slowdown text?

    unknown "This, my friend, is a JigBuddy!"

    unknown "It’s a special friend that will dance and boogie to any music!"

    "He proceeds to demonstrate by taking out an old looking mp3 player."

    "He selects a song and the strange mechanical creature jumps to life, its body swaying and bouncing to the rhythm of the music, making a series of robotic beeps and squeals in the process."

    "I really don’t want this thing.{w} In fact{w}, part of me wants to drop kick it."
    #a stop in between line
    "Unfortunately, I’m out of options and I need this address."

    "I get my wallet out, retrieve a 20, and hand it to him."

    unknown "You slumber a cucumber good sir!"

    "He hands me the strange device as well as a slip of paper with the address on it."

    "My breath quickens as excitement fills my body."

    A "Thank you so much! You just saved our Christmas!"

    unknown "You are quite welcome my cue ball shaped friend. Do come back soon!"

    "I barely register his mockery as I quickly turn around and start jogging towards the music store."

    show Anon:
        xzoom 1.0
        linear 0.75 xcenter 1.25
    with Dissolve(0.25)

    scene black with Dissolve(1)

    "Pulling up the address on my phone, it’s kind of hard to tell exactly where it is."

    "It takes me a bit, but I finally find the place."

    "It’s crammed down an alley that I never would have noticed on my own"

    scene storeoutside with Dissolve(1)
    show Anon ChristNeut with easeinleft:
        xcenter 0.20

    "...wait"
    #I will probably remake this line, so the last one is slow one

    "As I approach the address, I see that it isn’t a music store."

    "A sandwich board outside the door reads “Antiques.”"

    "Fuuuuuck!"

    "I asked for a music store! Why would Reed’s uncle send me here?!"

    "Did I just get hustled?!"

    "Damn it! I went through the trouble of running here, I might as well take a look."
    #Anon slides to the right as the scene goes black
    scene black with Dissolve(1)
    stop ambient
    play music 'audio/OST/Appreciating the Moment.ogg' fadein 4 volume 0.7

    "The old metal door creaks loudly as I enter. I’m immediately hit by the smell of old, musty knicknacks."

    scene Antique with Dissolve(1)
    show Anon ChristNeut with easeinleft:
        xcenter 0.23

    show potionseller:
        xpos 0.35
    with Dissolve(0.30)
    "It’s a small place, only marginally bigger than my old shithole in Skin Row."

    show potionseller:
        xzoom -1.0
    with Dissolve(0.30)

    "An old looking Iguanodon woman sits behind the counter. Large glasses are perched on her face."

    "Her head perks up as I enter, and she squints as she looks at me."

    OldLady "Ah… hello there dearie, what brings you in this evening?"
    #old lady, just gonna make a define for this, same colour as Reed's Uncle
    A "Well…  I’ve been looking all day for a guitar. Someone gave me the address of this place when I asked them if there were any music shops around here."

    A "You wouldn’t happen to have any guitars here, would you?"

    OldLady "A Guitar?"
    #old lady

    "She scratches her head as she ponders my question."

    OldLady "I’m not sure if we have one."

    OldLady "Let me check the back."
    #she turns to right and moves off screen before returning back
    show potionseller:
        xzoom 1.0
        linear 0.65 xcenter 1.40

    "She leaves me at the front. Worry and uncertainty rack my brain."

    show Anon ChristNeut:
        xzoom -1.0

    "I pace around, looking at the various items for what feels like forever."

    show Anon ChristNeut:
        xzoom 1.0

    show potionseller:
        xzoom -1.0
        linear 0.65 xcenter 0.75

    "She comes back empty handed."

    OldLady "I’m sorry young man, I didn’t find any guitars in the back."
    #old lady

    "I close my eyes and let out a long sigh."

    "That’s it… that was my last chance."
    #slow down

    "I’ll need to figure out something else then."

    show Anon ChristPain with dissolve

    A "Thank you anyway ma’am. I guess I’ll need to find something else for my wife."

    OldLady "Oh, if you’re looking for a nice gift, there’s plenty of items here that she might also like."
    #old lady

    A "...maybe you’re right. I’m kind of out of options so I’ll have a look around."

    show potionseller:
        xzoom 1.0
        linear 0.65 xcenter 1.40

    "I start to pace around the store, scanning the various antiques."

    show Anon ChristNeut:
        linear 0.60 xcenter 0.65

    "Pretty much all of these would probably be better suited for Samantha."

    show Anon ChristNeut:
        xzoom -1.0
        linear 0.60 xcenter 0.30

    "Just as I’m starting to lose hope for what may be the 10th time tonight, something catches my eye."

    "There is a pile of old clothes on a low shelf, but what stands out is something orange slightly sticking out from under them."

    "I can hardly believe what I see as I pull the clothes off of it."
    #shuffling sfx? also item sprite?

    "It’s a guitar!"

    "And not just any guitar, a beautiful electric one at that!"

    "The body is inlaid with a beautiful amber material that refracts the light as I tilt it in my hands."

    "The edges seem almost burnt as there’s a black, charred looking outline around the edges."

    "The fretboard is also black, but it’s accented with that same amber material."

    "It's… perfect."
    #insert Scout voiceline here

    "I hurriedly rush up to the counter. The woman sees me and smiles."

    show Anon ChristHapp:
        xzoom 1.0
        linear 0.60 xcenter 0.40
    show potionseller with easeinright:
        xzoom -1.0
        xcenter 0.70

    "I put the guitar in front of her; the biggest grin on my face."

    A "Look what I found!"
    #don't forget to create the last acts
    jump NAct3